Arduboyで狙い撃つぜ！（atan2テーブルの作り方） その１０

31x23マスのテーブルを作成していたが、0〜90度のデータがあれば（下図の赤い部分）
他の角度のデータを求めることができる。

16x12マスのレーダー法テーブルを作成する。

# 64方向
for y in range(12):
    for x in range(16):
        # ラジアンから度へ変換する
        angle = math.atan2(y, x) * 180 / math.pi
        # 角度を64分割した場合どの値になるか求める
        idx = round(angle / (360 / 64))
        # プラスの値にする
        if idx < 0:
            idx += 64
        print(format(idx, '#2') + ',', end='')
    print('')

http://beach.biwako.ne.jp/~beaver/msx/msxtecho/tablsp5.htm
BASICで書かれている1160行目を、getAtan2関数で再現する。

DX=(HX(0)-HX(1)+8)/16
DY=(HY(0)-HY(1)+8)/16
AG=RT(ABS(DX),ABS(DY))
IF DX<0 THEN
  IF DY<0 THEN
    AG=16+AG
  ELSE
    AG=16-AG
ELSE IF DY<0 THEN 
  AG=31AND(-AG)

Arduboyの画面では、Y軸は下方向がプラスなので、
XYのグラフが上下逆になっている点に注意する。

#include <Arduboy2.h>

Arduboy2 arduboy;

#define BOSS_SHOT   10

typedef struct CharaData {
  float x, y;
  float vx, vy;
  int life;
};

CharaData player;

CharaData boss;
CharaData bossShot[BOSS_SHOT];

uint16_t counter;

// 64方向の1/4のデータ（0°〜90°未満）
const float sinTbl[] PROGMEM = {
  0.0,
  0.0980171403295606,
  0.19509032201612825,
  0.29028467725446233,
  0.3826834323650898,
  0.47139673682599764,
  0.5555702330196022,
  0.6343932841636455,
  0.7071067811865475,
  0.7730104533627369,
  0.8314696123025451,
  0.8819212643483549,
  0.9238795325112867,
  0.9569403357322089,
  0.9807852804032304,
  0.9951847266721968,
};

float getSin(int16_t angle)
{
  float result = 1.f;
  uint8_t idx = angle & 0x1f;

  if (idx < 16) {
    result = pgm_read_float(sinTbl + idx);
  } else if (idx > 16) {
    result = pgm_read_float(sinTbl + 32 - idx);
  }

  return (angle & 0x3f) > 32 ? -result : result;
}

float getCos(int16_t angle)
{
  return getSin(16 + angle);
}

// レーダー法のテーブル（64方向の1/4のデータ）
const uint8_t radarTbl[] PROGMEM = {
   0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0,
  16, 8, 5, 3, 2, 2, 2, 1, 1, 1, 1, 1, 1, 1, 1, 1,
  16,11, 8, 6, 5, 4, 3, 3, 2, 2, 2, 2, 2, 2, 1, 1,
  16,13,10, 8, 7, 6, 5, 4, 4, 3, 3, 3, 2, 2, 2, 2,
  16,14,11, 9, 8, 7, 6, 5, 5, 4, 4, 4, 3, 3, 3, 3,
  16,14,12,10, 9, 8, 7, 6, 6, 5, 5, 4, 4, 4, 3, 3,
  16,14,13,11,10, 9, 8, 7, 7, 6, 6, 5, 5, 4, 4, 4,
  16,15,13,12,11,10, 9, 8, 7, 7, 6, 6, 5, 5, 5, 4,
  16,15,14,12,11,10, 9, 9, 8, 7, 7, 6, 6, 6, 5, 5,
  16,15,14,13,12,11,10, 9, 9, 8, 7, 7, 7, 6, 6, 6,
  16,15,14,13,12,11,10,10, 9, 9, 8, 8, 7, 7, 6, 6,
  16,15,14,13,12,12,11,10,10, 9, 8, 8, 8, 7, 7, 6,
};

//               |Y(-)
//               |
//     第3象限    |    第4象限
//               |
//               |
// --------------+--------------
// X(-)          |          X(+)
//               |
//     第2象限    |    第1象限
//               |
//               |Y(+)
int16_t getAtan2(float y, float x)
{
  // 1マスを8ドットとし、どのマスに該当するか求める
  int16_t dx = x / 8.f;
  int16_t dy = y / 8.f;

  // テーブルには第1象限のデータが入っている
  int16_t ag = pgm_read_byte(radarTbl + abs(dx) + abs(dy) * 16);

  if (dx < 0) {
    if (dy < 0) {
      // 第3象限
      ag += 32;
    } else {
      // 第2象限
      ag = 32 - ag;
    }
  } else if (dy < 0) {
    // 第4象限
    ag = 64 - ag;
  }

  return ag;
}

void setup()
{
  arduboy.begin();

  player.x = 20;
  player.y = 64 / 2;
  
  boss.x = 128 / 2;
  boss.y = 64 / 2;
}

void loop()
{
  if (!arduboy.nextFrame()) return;
  arduboy.clear();

 if (arduboy.pressed(LEFT_BUTTON)) {
    player.x -= 1.f;
  } else if (arduboy.pressed(RIGHT_BUTTON)) {
    player.x += 1.f;
  }
  if (arduboy.pressed(UP_BUTTON)) {
    player.y -= 1.f;
  } else if (arduboy.pressed(DOWN_BUTTON)) {
    player.y += 1.f;
  }
  arduboy.fillRect(player.x - 8.f, player.y - 4.f, 16, 8);

  // ボス（三角形）
  arduboy.drawTriangle(boss.x, boss.y - 8.f, boss.x - 8.f, boss.y + 8.f, boss.x + 8.f, boss.y + 8.f);

  // 弾の作成
  if (++counter % 10 == 0) {
    for (int16_t i = 0; i < BOSS_SHOT; ++i) {
      CharaData *p = &bossShot[i];
      if (p->life == 0) {
        // 弾を使用中にする
        p->life = 1;

        // 弾の初期位置をボスの中央にする
        p->x = boss.x;
        p->y = boss.y + 2.f;

        // プレイヤの方向を求める
        int16_t r = getAtan2(player.y - p->y, player.x - p->x);
        
        // 弾の移動方向を求める
        p->vx = getCos(r);
        p->vy = getSin(r);

        break;
      }
    }    
  }

  // 弾の表示
  for (int16_t i = 0; i < BOSS_SHOT; ++i) {
    CharaData *p = &bossShot[i];
    if (p->life > 0) {
      // 弾の移動
      p->x += p->vx;
      p->y += p->vy;

      // 画面外の弾を消す
      if (p->x < 0.f || 128.f < p->x || p->y < 0.f || 64.f < p->y)
        p->life = 0;

      arduboy.fillCircle(p->x, p->y, 2);
    }
  }

  arduboy.display();
}