Arduboyで弾幕的なものを その３

前回、一周を64方向と決めて、64個のデータを用意しましたが、
実は、16個（0°〜90°未満）あれば十分でした。

Pythonでsinテーブルを作成。

import math

for i in range(16):
    v = math.sin(i / 64 * 2 * math.pi)
    print(str(v) + ',')

#include <Arduboy2.h>

Arduboy2 arduboy;

#define BOSS_SHOT   10

typedef struct CharaData {
  float x, y;
  float vx, vy;
  int life;
};

CharaData boss;
CharaData bossShot[BOSS_SHOT];

uint16_t counter;
int16_t angle;

// 64方向の1/4のデータ（0°〜90°未満）
const float sinTbl[] PROGMEM = {
  0.0,
  0.0980171403295606,
  0.19509032201612825,
  0.29028467725446233,
  0.3826834323650898,
  0.47139673682599764,
  0.5555702330196022,
  0.6343932841636455,
  0.7071067811865475,
  0.7730104533627369,
  0.8314696123025451,
  0.8819212643483549,
  0.9238795325112867,
  0.9569403357322089,
  0.9807852804032304,
  0.9951847266721968,
};

float getSin(int16_t angle)
{
  float result = 1.f;  // 90°をデフォルト値にする
  uint8_t idx = angle & 0x1f; // マスクし、0〜31（0°〜180°未満）にする

  if (idx < 16) {
    // 0°〜90°未満のデータは用意しているので、そのまま求まる
    result = pgm_read_float(sinTbl + idx);
  } else if (idx > 16) {
    // 90°より大〜180°未満の値は、90°からテーブルを折り返すことで求まる
    result = pgm_read_float(sinTbl + 32 - idx);
  }

  // マスクし、0〜63（0°〜360°未満）にする
  // 33〜63（180°より大〜360°未満）の時は符号をマイナスにする
  return ((angle & 0x3f) > 32) ? -result : result;
}

float getCos(int16_t angle)
{
  return getSin(16 + angle);
}

void setup()
{
  arduboy.begin();
  arduboy.setFrameRate(60);
  arduboy.clear();

  // ボス（三角形）を画面中央に表示する
  boss.x = 128 / 2;
  boss.y = 64 / 2;
}

void loop()
{
  if (!arduboy.nextFrame()) return;
  arduboy.clear();

  // ボス（三角形）
  arduboy.drawTriangle(boss.x, boss.y - 8.f, boss.x - 8.f, boss.y + 8.f, boss.x + 8.f, boss.y + 8.f);

  // 弾の作成
  if (++counter % 10 == 0) {
    for (int8_t i = 0; i < BOSS_SHOT; ++i) {
      CharaData *p = &bossShot[i];
      if (p->life == 0) {
        // 弾を使用中にする
        p->life = 1;

        // 弾の初期位置をボスの中央にする
        p->x = boss.x;
        p->y = boss.y + 2.f;

        ++angle;

        // 弾の移動方向を求める
        p->vx = getCos(angle);
        p->vy = getSin(angle);

        break;
      }
    }    
  }

  // 弾の表示
  for (int16_t i = 0; i < BOSS_SHOT; ++i) {
    CharaData *p = &bossShot[i];
    if (p->life > 0) {
      // 弾の移動
      p->x += p->vx;
      p->y += p->vy;

      // 画面外の弾を消す
      if (p->x < 0.f || 128.f < p->x || p->y < 0.f || 64.f < p->y)
        p->life = 0;

      arduboy.fillCircle(p->x, p->y, 2);
    }
  }

  arduboy.display();
}