Arduboyで弾幕的なものを その１

弾幕薄いぞ。何やってんの！

sin,cos関数で弾幕的なものを。

#include <Arduboy2.h>

Arduboy2 arduboy;

#define PI 3.141592653589793f

#define BOSS_SHOT   10

typedef struct CharaData {
  float x, y;
  float vx, vy;
  int life;
};

CharaData boss;
CharaData bossShot[BOSS_SHOT];

uint16_t angle;

void setup()
{
  arduboy.begin();
  arduboy.setFrameRate(60);
  arduboy.clear();

  // ボス（三角形）を画面中央に表示する
  boss.x = 128 / 2;
  boss.y = 64 / 2;
}

void loop()
{
  if (!arduboy.nextFrame()) return;
  arduboy.pollButtons();
  arduboy.clear();

  // ボス（三角形）
  arduboy.drawTriangle(boss.x, boss.y - 8.0f, boss.x - 8.0f, boss.y + 8.0f, boss.x + 8.0f, boss.y + 8.0f);

  // 弾の作成
  if (++angle % 10 == 0) {
    for (int8_t i = 0; i < BOSS_SHOT; i++) {
      CharaData *p = &bossShot[i];
      if (p->life == 0) {
        // 弾を使用中にする
        p->life = 1;

        // 弾の初期位置をボスの中央にする
        p->x = boss.x;
        p->y = boss.y + 2.0f;

        // 角度をラジアンに変換する
        float r = angle * PI / 180.0f;

        // 弾の移動方向を求める
        p->vx = cosf(r);
        p->vy = sinf(r);

        break;
      }
    }    
  }

  // 弾の表示
  for (int16_t i = 0; i < BOSS_SHOT; i++) {
    CharaData *p = &bossShot[i];
    if (p->life > 0) {
      // 弾の移動
      p->x += p->vx;
      p->y += p->vy;

      // 画面外の弾を消す
      if (p->x < 0.0f || 128.0f < p->x || p->y < 0.0f || 64.0f < p->y)
        p->life = 0;

      arduboy.fillCircle(p->x, p->y, 2);
    }
  }

  arduboy.display();
}